'From Squeak3.6 of ''6 October 2003'' [latest update: #5429] on 28 August 2004 at 1:34:40 pm'!
WAReportColumn subclass: #SCReportColumn
	instanceVariableNames: 'cssClass renderBlock '
	classVariableNames: ''
	poolDictionaries: ''
	category: 'SC-Components'!

!SCReportColumn methodsFor: 'rendering' stamp: 'cds 8/28/2004 13:23'!
renderCellForRow: aRow on: html 
	self cssClass
		ifNotNil: [html cssClass: self cssClass].
	self renderBlock
				value: aRow
				value: self
				value: html! !

!SCReportColumn methodsFor: 'rendering' stamp: 'cds 8/27/2004 21:42'!
renderFooterOn: html forRows: rows 
	cssClass
		ifNotNil: [html cssClass: cssClass].
	html
		tableHeading: [html
				text: (self totalForRows: rows)]! !

!SCReportColumn methodsFor: 'rendering' stamp: 'cds 8/28/2004 12:52'!
renderHeaderOn: html sortBlock: aBlock sorted: sorted reversed: reversed 
	| sortedString |
	sortedString _ sorted
				ifTrue: [reversed
						ifTrue: ['(-)']
						ifFalse: ['(+)']]
				ifFalse: [''].
	cssClass
		ifNotNil: [html cssClass: cssClass].
	html
		tableHeading: [self canSort
				ifTrue: [html anchorWithAction: aBlock text: self title , sortedString]
				ifFalse: [html text: self title , sortedString]]! !

!SCReportColumn methodsFor: 'rendering' stamp: 'cds 8/28/2004 13:11'!
textForRow: row 
	| text |
	text _ formatBlock
		value: (self valueForRow: row).
	text ifEmpty: [^' '].
	^text! !


!SCReportColumn methodsFor: 'accessing' stamp: 'cds 8/25/2004 17:59'!
cssClass
	^cssClass! !

!SCReportColumn methodsFor: 'accessing' stamp: 'cds 8/25/2004 17:59'!
cssClass: anObject
	cssClass := anObject! !

!SCReportColumn methodsFor: 'accessing' stamp: 'cds 8/28/2004 13:07'!
renderBlock
	^renderBlock! !

!SCReportColumn methodsFor: 'accessing' stamp: 'cds 8/28/2004 13:07'!
renderBlock: anObject
	renderBlock := anObject! !


!SCReportColumn methodsFor: 'initialization' stamp: 'cds 8/28/2004 13:23'!
initialize
	super initialize.
	renderBlock _ [:row :col :html | html tableData: [self canChoose
				ifTrue: [html
						anchorWithAction: [self chooseRow: row]
						text: (self textForRow: row)]
				ifFalse: [html
						text: (self textForRow: row)]]]! !